列举网络芳邻的网络资源

此范例会以递归方式列举网络芳邻的网络资源，在此范例中会使用到 mpr.dll API 函式库的 WNetEnumResource、WNetOpenEnum、WNetCloseEnum 函式来进行网络芳邻的网络资源的列举动作。

TAPIMpr 类别为 mpr.dll API 函式库的操作类别

    ''' <summary>
    ''' 网络芳邻相关函式库(mpr.dll)。
    ''' </summary>
    Public NotInheritable Class TAPIMpr
        Public Enum EResourceScope As Integer
            ''' <summary>
            ''' 正联机的资源。
            ''' </summary>
            RESOURCE_CONNECTED = &H1
            ''' <summary>
            ''' 网络上所有的资源。
            ''' </summary>
            RESOURCE_GLOBALNET = &H2
            ''' <summary>
            ''' 曾经联机的资源。
            ''' </summary>
            RESOURCE_REMEMBERED = &H3
        End Enum

        Public Enum EResourceType As Integer
            ''' <summary>
            ''' 所有网络资源。
            ''' </summary>
            RESOURCETYPE_ANY = &H0
            ''' <summary>
            ''' 网络磁盘驱动器。
            ''' </summary>
            RESOURCETYPE_DISK = &H1
            ''' <summary>
            ''' 网络打印机。
            ''' </summary>
            RESOURCETYPE_PRINT = &H2
            ''' <summary>
            ''' 未知。
            ''' </summary>
            RESOURCETYPE_UNKNOWN = &HFFFFFFFF
        End Enum

        Public Enum EResourceDisplayType As Integer
            ''' <summary>
            ''' 一般资源。
            ''' </summary>
            RESOURCEDISPLAYTYPE_GENERIC = 0
            ''' <summary>
            ''' 网域资源。
            ''' </summary>
            RESOURCEDISPLAYTYPE_DOMAIN = 1
            ''' <summary>
            ''' 服务器资源。
            ''' </summary>
            RESOURCEDISPLAYTYPE_SERVER = 2
            ''' <summary>
            ''' 共享资源。
            ''' </summary>
            RESOURCEDISPLAYTYPE_SHARE = 3
            ''' <summary>
            ''' 档案资源。
            ''' </summary>
            RESOURCEDISPLAYTYPE_FILE = 4
            RESOURCEDISPLAYTYPE_GROUP = 5
            RESOURCEDISPLAYTYPE_NETWORK = 6
            RESOURCEDISPLAYTYPE_ROOT = 7
            RESOURCEDISPLAYTYPE_SHAREADMIN = 8
            RESOURCEDISPLAYTYPE_DIRECTORY = 9
            RESOURCEDISPLAYTYPE_TREE = 10
            RESOURCEDISPLAYTYPE_NDSCONTAINER = 11
        End Enum

        Public Enum EResourceUsage As Integer
            RESOURCEUSAGE_CONNECTABLE = &H1
            RESOURCEUSAGE_CONTAINER = &H2
            RESOURCEUSAGE_NOLOCALDEVICE = &H4
            RESOURCEUSAGE_SIBLING = &H8
            RESOURCEUSAGE_ATTACHED = &H10
            RESOURCEUSAGE_ALL = (RESOURCEUSAGE_CONNECTABLE Or RESOURCEUSAGE_CONTAINER Or RESOURCEUSAGE_ATTACHED)
            RESOURCEUSAGE_RESERVED = &H80000000
        End Enum

        ''' <summary>
        ''' 网络资源定义。
        ''' </summary>
        <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Auto)> _
        Public Class TNetResource
            Public dwScope As EResourceScope
            Public dwType As EResourceType
            Public dwDisplayType As EResourceDisplayType
            Public dwUsage As EResourceUsage
            <MarshalAs(UnmanagedType.LPTStr)> _
            Public LocalName As String
            <MarshalAs(UnmanagedType.LPTStr)> _
            Public RemoteName As String
            <MarshalAs(UnmanagedType.LPTStr)> _
            Public Comment As String
            <MarshalAs(UnmanagedType.LPTStr)> _
            Public Provider As String
        End Class

        ''' <summary>
        ''' 列举网络芳邻的网络资源。
        ''' </summary>
        ''' <param name="Handle">从 WNetOpenEnum 函数返回的一个句柄。</param>
        ''' <param name="Count">最初设为要枚举的最大资源数量；或设为-1，表示枚举尽可能多的资源。一旦返回，就会设为实际枚举的资源数量。</param>
        ''' <param name="NetResource">通常是一个字节缓冲区的首字节。该缓冲区装载了列举信息。</param>
        ''' <param name="Size">缓冲区大小。</param>
        <DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
Public Shared Function WNetEnumResource(ByVal Handle As IntPtr, ByRef Count As Integer, ByVal NetResource As IntPtr, ByRef Size As Integer) As Integer
        End Function

        ''' <summary>
        ''' 启动对网络资源进行列举的过程。这个函数会返回由 WNetEnumResource 函数用于列举资源所用的一个句柄。
        ''' </summary>
        ''' <param name="Scope">要列举的资源范围。</param>
        ''' <param name="Type">要列举的资源类型。</param>
        ''' <param name="Usage">要列举的资源使用状况。</param>
        ''' <param name="NetResource">网络资源定义。</param>
        ''' <param name="Handle">传出一个句柄。该句柄由 WNetEnumResource 函数使用。必须用 WNetCloseEnum 函数将其清除。</param>
        <DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
        Public Shared Function WNetOpenEnum(ByVal Scope As EResourceScope, ByVal Type As EResourceType, ByVal Usage As EResourceUsage, ByVal NetResource As TNetResource, <Out()> ByRef Handle As IntPtr) As Integer
        End Function

        ''' <summary>
        ''' 结束列举操作。
        ''' </summary>
        ''' <param name="Handle">由 WNetOpenEnum 函数返回的一个列举句柄。</param>
        <DllImport("mpr.dll", CharSet:=CharSet.Auto)> _
        Public Shared Function WNetCloseEnum(ByVal Handle As IntPtr) As Integer
        End Function

    End Class

 

下列程序代码中的 NetEnumResource 为列举网络芳邻的网络资源的函式，NetEnumResourceCallback 为执行 NetEnumResource 方法的回呼函式。

        ''' <summary>
        ''' 执行 NetEnumResource 方法的回呼函式。
        ''' </summary>
        ''' <param name="NetResource">网络资源定义。</param>
        ''' <param name="Cancel">是否取消列举动作。</param>
        Public Delegate Sub NetEnumResourceCallback(ByVal NetResource As TAPIMpr.TNetResource, ByRef Cancel As Boolean)

        ''' <summary>
        ''' 列举网络芳邻的网络资源。
        ''' </summary>
        ''' <param name="NetResource">网络资源定义。</param>
        ''' <param name="CallBack">列举过程中的回呼函式。</param>
        Public Shared Sub NetEnumResource(ByVal NetResource As TAPIMpr.TNetResource, ByVal CallBack As NetEnumResourceCallback)
            Dim bCancel As Boolean
            Dim iRet As Integer
            Dim oHandle As IntPtr = New IntPtr()
            Dim iEntries As Integer
            Dim iBuffer As Integer = 16384
            Dim oBuffer As IntPtr
            Dim oNetResource As TAPIMpr.TNetResource
            Dim iPtr As Int32
            Dim N1 As Integer
            Dim oStructure As Object

            bCancel = False
            Try
                iRet = TAPIMpr.WNetOpenEnum( _
                    TAPIMpr.EResourceScope.RESOURCE_GLOBALNET, _
                    TAPIMpr.EResourceType.RESOURCETYPE_ANY, _
                    TAPIMpr.EResourceUsage.RESOURCEUSAGE_ALL, NetResource, oHandle)
                If iRet <> 0 Then Exit Sub

                oBuffer = Marshal.AllocHGlobal(iBuffer)
                Do
                    iEntries = -1
                    iBuffer = 16384
                    iRet = TAPIMpr.WNetEnumResource(oHandle, iEntries, oBuffer, iBuffer)
                    If iRet <> 0 OrElse iEntries < 1 Then Exit Sub
                    iPtr = oBuffer.ToInt32
                    For N1 = 0 To iEntries - 1
                        oStructure = Marshal.PtrToStructure(CType(iPtr, IntPtr), GetType(TAPIMpr.TNetResource))
                        oNetResource = DirectCast(oStructure, TAPIMpr.TNetResource)

                        '列举过程中的回呼函式
                        CallBack.Invoke(oNetResource, bCancel)
                        If bCancel = True Then Exit Do

                        '若为 RESOURCEUSAGE_CONTAINER 则利用递归往下层列举网络资源
                        If (TAPIMpr.EResourceUsage.RESOURCEUSAGE_CONTAINER = _
                           (oNetResource.dwUsage And TAPIMpr.EResourceUsage.RESOURCEUSAGE_CONTAINER)) Then
                            NetEnumResource(oNetResource, CallBack)
                        End If
                        iPtr = iPtr + Marshal.SizeOf(oNetResource)
                    Next
                Loop

                Marshal.FreeHGlobal(oBuffer)
                TAPIMpr.WNetCloseEnum(oHandle)
            Catch ex As Exception
            End Try
        End Sub

 

在窗体上放置一个 ListBox 控件来显示列举的网络资源，呼叫 NetEnumResource 函式来进行列举，呼叫 NetEnumResource 函式的自变量需传入事先定义好的 NetEnumResourceCallback 回呼函式；当列举的过程序，当找到网络资源时就会执行 NetEnumResourceCallback 函式，利用传入的 NetResource 自变量就可以依序列举网络资源。

    ''' <summary>
    ''' 执行 WNetEnumResource 方法的回呼函式。
    ''' </summary>
    ''' <param name="NetResource">网络资源定义。</param>
    ''' <param name="Cancel">是否取消列举动作。</param>
    Public Sub NetEnumResourceCallback(ByVal NetResource As TAPIMpr.TNetResource, ByRef Cancel As Boolean)
        Dim sText As String

        sText = String.Format(" {0} : LocalName='{1}' RemoteName='{2}'", NetResource.dwDisplayType.ToString, NetResource.LocalName, NetResource.RemoteName)
        ListBox1.Items.Add(sText)
        Application.DoEvents()
    End Sub

    Private Sub Button10_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button10.Click
        Me.Cursor = Cursors.WaitCursor
        Try
            ListBox1.Items.Clear()
            TBMpr.NetEnumResource(Nothing, New NetEnumResourceCallback(AddressOf NetEnumResourceCallback))
            MsgBox("执行完成!")
        Finally
            Me.Cursor = Cursors.Default
        End Try
    End Sub